You have come to a major crossroads. The southern route winds around mountains and along uninhabited sea
cliffs, heading nearly backwards at several points. The other routes are more direct, especially the western
one, but the western route cuts through a much more dangerous region, while passing through the multiple
kingdoms to the north means paying many more tolls.

*set time +1

*temp asked
*set asked 0
*label top
*choice  
	#Take northerly toll road.
		The caravan takes the northern fork into the toll region. You soon find yourself before a toll to 
		pay.
		
		*temp oldfunds
		*set oldfunds funds
		*if (funds < 100)
			*set funds 0
			*goto paid
		*elseif (funds < 300)
			*set funds (50 + (dedication * 2))
			*goto paid
		*elseif (funds < 500)
			*set funds (250 + (dedication * 2))
			*goto paid
		*elseif (funds < 800)
			*set funds (400 + (dedication * 3))
			*goto paid
		*elseif (funds < 1100)
			*set funds (700 + (dedication * 3))
			*goto paid
		*elseif (funds < 1500)
			*set funds (950 + (dedication * 4))
			*goto paid
		*elseif (funds < 1900)
			*set funds (1350 + (dedication * 4))
			*goto paid
		*elseif (funds < 2400)
			*set funds (1700 + (dedication * 5))
			*goto paid
		*elseif (funds < 3000)
			*set funds (2150 + (dedication * 6))
			*goto paid
		
		*label paid
		*set misc_outlay (misc_outlay + (oldfunds - funds))
		You're left with ${funds} after paying the early tolls. 
		*if (funds < 11)
			This may be a problem.
		*set region "kingdoms"
		*set speed (animals + 4)
		*finish
	#Take southerly route along the mountains.
		It's slow going, but your caravan begins winding its way along the base of the mountains.
		*set region "mountains"
		*set speed (animals + 1)
		*finish
	#Take western route through the flatlands.
		The caravan sets off on the direct route to the west.
		*set region "flatlands"
		*set speed (animals + 3)
		*finish
	*if (asked < 3) #Ask for advice from another merchant.
		*set Leadership (Leadership %+ (10 - (5 * asked)))
			
		Who will you ask?
		*choice
			*hide_reuse #Ephraim.
				*set asked +1
				*if (Leadership > 50)
					"I recommend the path along the mountains. I took that the last time I came through here.
					Going that way may be slow, but it's safe and there are few tolls."
					*goto top
				*else
					"Oh, I couldn't tell you what to do. You're the leader of this expedition, I trust your
					decision." He seems distracted.
					*goto top
			*hide_reuse #Alexander.
				*set asked +1
				*if (Leadership > 70)
					He looks at you with eyes narrowed as you approach, but says, "I'd take the west route. 
					It's the most direct and fastest way through."
					*goto top
				*else
					He blows you off, saying something about being too busy to meet with you.
					*set alexander %-10
					*goto top
			*hide_reuse #Yishai.
				*set asked +1
				"Hmm." He's impossible to read, with his face behind that covering of his. "I really can't
				say."
				*set yishai %+10
				*goto top